{-# LANGUAGE
    GeneralizedNewtypeDeriving
  , OverloadedStrings
  , UnicodeSyntax
  #-}
module Network.HTTP.Lucu.Headers
    ( Headers
    , HasHeaders(..)

    , toHeaders
    , fromHeaders

    , headersP
    , printHeaders
    )
    where
import Control.Applicative
import Data.Ascii (Ascii, AsciiBuilder, CIAscii)
import qualified Data.Ascii as A
import Data.Attoparsec.Char8 as P
import qualified Data.ByteString as BS
import Data.Map (Map)
import qualified Data.Map as M
import Data.Monoid
import Data.Monoid.Unicode
import Network.HTTP.Lucu.Parser.Http
import Network.HTTP.Lucu.Utils
import Prelude.Unicode

newtype Headers
    = Headers (Map CIAscii Ascii)
      deriving (Eq, Show, Monoid)

class HasHeaders a where
    getHeaders ∷ a → Headers
    setHeaders ∷ a → Headers → a

    getHeader ∷ CIAscii → a → Maybe Ascii
    getHeader key a
        = case getHeaders a of
            Headers m → M.lookup key m

    getCIHeader ∷ CIAscii → a → Maybe CIAscii
    {-# INLINE getCIHeader #-}
    getCIHeader key a
        = A.toCIAscii <$> getHeader key a

    deleteHeader ∷ CIAscii → a → a
    {-# INLINE deleteHeader #-}
    deleteHeader key a
        = case getHeaders a of
            Headers m
              → setHeaders a $ Headers $ M.delete key m

    setHeader ∷ CIAscii → Ascii → a → a
    {-# INLINE setHeader #-}
    setHeader key val a
        = case getHeaders a of
            Headers m
              → setHeaders a $ Headers $ M.insert key val m

instance HasHeaders Headers where
    getHeaders   = id
    setHeaders _ = id

toHeaders ∷ [(CIAscii, Ascii)] → Headers
{-# INLINE toHeaders #-}
toHeaders = flip mkHeaders (∅)

mkHeaders ∷ [(CIAscii, Ascii)] → Headers → Headers
mkHeaders []              (Headers m) = Headers m
mkHeaders ((key, val):xs) (Headers m)
    = mkHeaders xs $ Headers $
      case M.lookup key m of
        Nothing  → M.insert key val m
        Just old → M.insert key (merge old val) m
    where
      merge ∷ Ascii → Ascii → Ascii
      {-# INLINE merge #-}
      merge a b
          | nullA a ∧ nullA b = (∅)
          | nullA a           = b
          |           nullA b = a
          | otherwise         = a ⊕ ", " ⊕ b

      nullA ∷ Ascii → Bool
      {-# INLINE nullA #-}
      nullA = BS.null ∘ A.toByteString

fromHeaders ∷ Headers → [(CIAscii, Ascii)]
fromHeaders (Headers m) = M.toList m

{-
  message-header = field-name ":" [ field-value ]
  field-name     = token
  field-value    = *( field-content | LWS )
  field-content  = <field-value を構成し、*TEXT あるいは
                    token, separators, quoted-string を連結
                    したものから成る OCTET>

  field-value の先頭および末尾にある LWS は全て削除され、それ以外の
  LWS は單一の SP に變換される。
-}
headersP ∷ Parser Headers
{-# INLINEABLE headersP #-}
headersP = do xs ← P.many header
              crlf
              return $ toHeaders xs
    where
      header ∷ Parser (CIAscii, Ascii)
      header = do name ← A.toCIAscii <$> token
                  _    ← char ':'
                  skipMany lws
                  values ← sepBy content (try lws)
                  skipMany (try lws)
                  crlf
                  return (name, joinValues values)

      content ∷ Parser Ascii
      {-# INLINE content #-}
      content = A.unsafeFromByteString
                <$>
                takeWhile1 (\c → ((¬) (isSPHT c)) ∧ isText c)

      joinValues ∷ [Ascii] → Ascii
      {-# INLINE joinValues #-}
      joinValues = A.fromAsciiBuilder ∘ joinWith "\x20" ∘ map A.toAsciiBuilder

printHeaders ∷ Headers → AsciiBuilder
printHeaders (Headers m)
    = mconcat (map printHeader (M.toList m)) ⊕
      A.toAsciiBuilder "\x0D\x0A"
    where
      printHeader ∷ (CIAscii, Ascii) → AsciiBuilder
      printHeader (name, value)
          = A.toAsciiBuilder (A.fromCIAscii name) ⊕
            A.toAsciiBuilder ": "                 ⊕
            A.toAsciiBuilder value                ⊕
            A.toAsciiBuilder "\x0D\x0A"