-- | The entry point of Lucu httpd.
module Network.HTTP.Lucu.Httpd
    ( runHttpd
    )
    where

import           Control.Concurrent
import           Network
import           Network.HTTP.Lucu.Config
import           Network.HTTP.Lucu.Interaction
import           Network.HTTP.Lucu.RequestReader
import           Network.HTTP.Lucu.Resource.Tree
import           Network.HTTP.Lucu.ResponseWriter
import           System.Posix.Signals

-- | This is the entry point of Lucu httpd. It listens to a socket and
-- waits for clients. Computation of 'runHttpd' never stops by itself
-- so the only way to stop it is to raise an exception in the thread
-- computing it.
--
-- Note that 'runHttpd' automatically makes SIGPIPE be ignored by
-- computing @installHandler sigPIPE Ignore Nothing@. This can hardly
-- cause a problem but it may do.
--
-- Example:
--
-- > module Main where
-- > import Network.HTTP.Lucu
-- > 
-- > main :: IO ()
-- > main = let config    = defaultConfig
-- >            resources = mkResTree [ ([], helloWorld) ]
-- >        in
-- >          runHttpd config resourcees
-- >
-- > helloWorld :: ResourceDef
-- > helloWorld = ResourceDef {
-- >                resUsesNativeThread = False
-- >              , resIsGreedy         = False
-- >              , resGet
-- >                  = Just $ do setContentType $ "text" </> "plain"
-- >                              output "Hello, world!"
-- >              , resHead   = Nothing
-- >              , resPost   = Nothing
-- >              , resPut    = Nothing
-- >              , resDelete = Nothing
-- >              }
runHttpd :: Config -> ResTree -> IO ()
runHttpd cnf tree
    = withSocketsDo $
      do installHandler sigPIPE Ignore Nothing
         so <- listenOn (cnfServerPort cnf)
         loop so
    where
      loop :: Socket -> IO ()
      loop so
          = do (h, host, _) <- accept so
               tQueue       <- newInteractionQueue
               readerTID    <- forkIO $ requestReader cnf tree h host tQueue
               writerTID    <- forkIO $ responseWriter cnf h tQueue readerTID
               loop so