module Network.HTTP.Lucu.MIMEType.Guess
    ( ExtMap
    , guessTypeByFileName -- ExtMap -> FilePath -> Maybe MIMEType

    , parseExtMapFile  -- FilePath -> IO ExtMap
    , outputExtMapAsHS -- ExtMap -> FilePath -> IO ()
    )
    where

import qualified Data.ByteString.Lazy.Char8 as B
import           Data.ByteString.Lazy.Char8 (ByteString)
import qualified Data.Map as M
import           Data.Map (Map)
import           Data.Maybe
import           Language.Haskell.Pretty
import           Language.Haskell.Syntax
import           Network.HTTP.Lucu.MIMEType
import           Network.HTTP.Lucu.Parser
import           Network.HTTP.Lucu.Parser.Http
import           Network.HTTP.Lucu.Utils
import           System.IO

type ExtMap = Map String MIMEType


guessTypeByFileName :: ExtMap -> FilePath -> Maybe MIMEType
guessTypeByFileName extMap fpath
    = let ext = head $ reverse $ splitBy (== '.') fpath
      in
        M.lookup ext extMap >>= return


parseExtMapFile :: FilePath -> IO ExtMap
parseExtMapFile fpath
    = do file <- B.readFile fpath
         case parse (allowEOF extMapP) file of
           (Success xs, _) -> return $ compile xs
           (_, input')     -> let near = B.unpack $ B.take 100 input'
                              in 
                                fail ("Failed to parse: " ++ fpath ++ " (near: " ++ near ++ ")")


extMapP :: Parser [ (MIMEType, [String]) ]
extMapP = do xs <- many (comment <|> validLine <|> emptyLine)
             eof
             return $ catMaybes xs
    where
      spc = oneOf " \t"

      comment = do many spc
                   char '#'
                   many $ satisfy (/= '\n')
                   return Nothing

      validLine = do many spc
                     mime <- mimeTypeP
                     many spc
                     exts <- sepBy token (many spc)
                     return $ Just (mime, exts)

      emptyLine = oneOf " \t\n" >> return Nothing


compile :: [ (MIMEType, [String]) ] -> Map String MIMEType
compile = M.fromList . foldr (++) [] . map tr
    where
      tr :: (MIMEType, [String]) -> [ (String, MIMEType) ]
      tr (mime, exts) = [ (ext, mime) | ext <- exts ]


outputExtMapAsHS :: ExtMap -> FilePath -> IO ()
outputExtMapAsHS extMap fpath
    = let hsModule = HsModule undefined modName (Just exports) imports decls
          modName  = Module "Network.HTTP.Lucu.MIMEType.DefaultExtensionMap"
          exports  = [HsEVar (UnQual (HsIdent "defaultExtensionMap"))]
          imports  = [ HsImportDecl undefined (Module "Network.HTTP.Lucu.MIMEType") False Nothing Nothing
                     , HsImportDecl undefined (Module "Data.Map") True (Just (Module "M")) Nothing
                     , HsImportDecl undefined (Module "Data.Map") False Nothing (Just (False, [HsIAbs (HsIdent "Map")]))
                     ]
          decls    = [ HsTypeSig undefined [HsIdent "defaultExtensionMap"]
                                     (HsQualType [] (HsTyApp (HsTyApp (HsTyCon (UnQual (HsIdent "Map")))
                                                                      (HsTyCon (UnQual (HsIdent "String"))))
                                                             (HsTyCon (UnQual (HsIdent "MIMEType")))))
                     , HsFunBind [HsMatch undefined (HsIdent "defaultExtensionMap")
                                  [] (HsUnGuardedRhs extMapExp) []]
                     ]
          extMapExp = HsApp (HsVar (Qual (Module "M") (HsIdent "fromList"))) (HsList records)
          comment =    "{- !!! WARNING !!!\n"
                    ++ "   This file is automatically generated from data/mime.types.\n"
                    ++ "   DO NOT EDIT BY HAND OR YOU WILL REGRET -}\n\n"
      in
        writeFile fpath $ comment ++ prettyPrint hsModule ++ "\n"
    where
      records :: [HsExp]
      records = map record $ M.assocs extMap

      record :: (String, MIMEType) -> HsExp
      record (ext, mime)
          = HsTuple [HsLit (HsString ext), mimeToExp mime]
                    
      mimeToExp :: MIMEType -> HsExp
      mimeToExp (MIMEType maj min params)
          = foldl appendParam (HsInfixApp
                               (HsLit (HsString maj))
                               (HsQVarOp (UnQual (HsSymbol "+/+")))
                               (HsLit (HsString min))) params

      appendParam :: HsExp -> (String, String) -> HsExp
      appendParam x param
          = HsInfixApp x (HsQVarOp (UnQual (HsSymbol "+:+"))) $ paramToExp param

      paramToExp :: (String, String) -> HsExp
      paramToExp (name, value)
          = HsInfixApp
            (HsLit (HsString name))
            (HsQVarOp (UnQual (HsSymbol "+=+")))
            (HsLit (HsString value))