module Network.HTTP.Lucu.Parser
    ( Parser(..)
    , parse     -- Parser a -> ByteString -> Maybe (a, ByteString)
    , anyChar   -- Parser Char
    , satisfy   -- (Char -> Bool) -> Parser Char
    , char      -- Char -> Parser Char
    , string    -- String -> Parser String
    , (<|>)     -- Parser a -> Parser a -> Parser a
    , oneOf     -- [Char] -> Parser Char
    , digit     -- Parser Char
    , notFollowedBy -- Parser a -> Parser ()
    , many      -- Parser a -> Parser [a]
    , many1     -- Parser a -> Parser [a]
    , manyTill  -- Parser a -> Parser end -> Parser [a]
    , many1Till -- Parser a -> Parser end -> Parser [a]
    , option    -- a -> Parser a -> Parser a
    , sp        -- Parser Char
    , ht        -- Parser Char
    , crlf      -- Parser String
    )
    where

import           Control.Monad
import           Control.Monad.State
import qualified Data.ByteString.Lazy.Char8 as B
import           Data.ByteString.Lazy.Char8 (ByteString)

data Parser a = Parser {
      runParser :: State ByteString (Maybe a)
    }


--  (>>=) :: Parser a -> (a -> Parser b) -> Parser b
instance Monad Parser where
    p >>= f = Parser $ do saved  <- get -- 失敗した時の爲に状態を保存
                          result <- runParser p
                          case result of
                            Just a  -> runParser (f a)
                            Nothing -> do put saved -- 状態を復歸
                                          return Nothing
    return = Parser . return . Just
    fail _ = Parser $ return Nothing


parse :: Parser a -> ByteString -> Maybe (a, ByteString)
parse p input = case runState (runParser p) input of
                  (Just a , input') -> Just (a, input')
                  (Nothing, _     ) -> Nothing


anyChar :: Parser Char
anyChar = Parser $ do input <- get
                      if B.null input then
                          return Nothing
                        else
                          do let c = B.head input
                             put (B.tail input)
                             return (Just c)


satisfy :: (Char -> Bool) -> Parser Char
satisfy f = do c <- anyChar
               unless (f c) (fail "")
               return c


char :: Char -> Parser Char
char c = satisfy (== c)


string :: String -> Parser String
string str = do mapM_ char str
                return str


infixr 0 <|>

(<|>) :: Parser a -> Parser a -> Parser a
f <|> g = Parser $ do saved  <- get -- 状態を保存
                      result <- runParser f
                      case result of
                        Just a  -> return (Just a)
                        Nothing -> do put saved -- 状態を復歸
                                      runParser g


oneOf :: [Char] -> Parser Char
oneOf = foldl (<|>) (fail "") . map char


notFollowedBy :: Parser a -> Parser ()
notFollowedBy p = p >>= fail "" <|> return ()


digit :: Parser Char
digit = oneOf "0123456789"


many :: Parser a -> Parser [a]
many p = do x  <- p
            xs <- many p
            return (x:xs)
         <|>
         return []


many1 :: Parser a -> Parser [a]
many1 p = do ret <- many p
             case ret of
               [] -> fail ""
               xs -> return xs


manyTill :: Parser a -> Parser end -> Parser [a]
manyTill p end = many $ do x <- p
                           end
                           return x


many1Till :: Parser a -> Parser end -> Parser [a]
many1Till p end = many1 $ do x <- p
                             end
                             return x


option :: a -> Parser a -> Parser a
option def p = p <|> return def


sp :: Parser Char
sp = char ' '


ht :: Parser Char
ht = char '\t'


crlf :: Parser String
crlf = string "\x0d\x0a"