{-# LANGUAGE
    OverloadedStrings
  , TemplateHaskell
  , UnicodeSyntax
  #-}
-- |Utility functions used internally in the Lucu httpd. These
-- functions may be useful too for something else.
module Network.HTTP.Lucu.Utils
    ( splitBy
    , quoteStr
    , parseWWWFormURLEncoded
    , splitPathInfo
    , trim
    , liftCIAscii
    , liftText
    , liftMap
    )
    where
import Control.Monad
import Data.Ascii (Ascii, CIAscii, AsciiBuilder)
import qualified Data.Ascii as A
import Data.ByteString (ByteString)
import qualified Data.ByteString.Char8 as BS
import Data.Char
import Data.List hiding (last)
import Data.Map (Map)
import qualified Data.Map as M
import Data.Monoid.Unicode
import Data.Text (Text)
import qualified Data.Text as T
import Language.Haskell.TH.Lib
import Language.Haskell.TH.Syntax
import Network.URI
import Prelude hiding (last)
import Prelude.Unicode

-- |>>> splitBy (== ':') "ab:c:def"
-- ["ab", "c", "def"]
splitBy ∷ (a → Bool) → [a] → [[a]]
{-# INLINEABLE splitBy #-}
splitBy isSep src
    = case break isSep src of
        (last , []       ) → [last]
        (first, _sep:rest) → first : splitBy isSep rest

-- |>>> quoteStr "abc"
-- "\"abc\""
--
-- >>> quoteStr "ab\"c"
-- "\"ab\\\"c\""
quoteStr ∷ Ascii → AsciiBuilder
quoteStr str = A.toAsciiBuilder "\"" ⊕
               go (A.toByteString str) (∅) ⊕
               A.toAsciiBuilder "\""
    where
      go ∷ BS.ByteString → AsciiBuilder → AsciiBuilder
      go bs ab
          = case BS.break (≡ '"') bs of
              (x, y)
                  | BS.null y → ab ⊕ b2ab x
                  | otherwise → go (BS.tail y) (ab ⊕ b2ab x
                                                   ⊕ A.toAsciiBuilder "\\\"")

      b2ab ∷ BS.ByteString → AsciiBuilder
      b2ab = A.toAsciiBuilder ∘ A.unsafeFromByteString

-- |>>> parseWWWFormURLEncoded "aaa=bbb&ccc=ddd"
-- [("aaa", "bbb"), ("ccc", "ddd")]
parseWWWFormURLEncoded ∷ Ascii → [(ByteString, ByteString)]
parseWWWFormURLEncoded src
    -- THINKME: We could gain some performance by using attoparsec
    -- here.
    | src ≡ ""  = []
    | otherwise = do pairStr ← splitBy (\ c → c ≡ ';' ∨ c ≡ '&') (A.toString src)
                     let (key, value) = break (≡ '=') pairStr
                     return ( unescape key
                            , unescape $ case value of
                                           ('=':val) → val
                                           val       → val
                            )
    where
      unescape ∷ String → ByteString
      unescape = BS.pack ∘ unEscapeString ∘ map plusToSpace

      plusToSpace ∷ Char → Char
      plusToSpace '+' = ' '
      plusToSpace c   = c

-- |>>> splitPathInfo "http://example.com/foo/bar"
-- ["foo", "bar"]
splitPathInfo ∷ URI → [ByteString]
splitPathInfo uri
    = let reqPathStr = uriPath uri
          reqPath    = [unEscapeString x | x ← splitBy (≡ '/') reqPathStr, (¬) (null x)]
      in
        map BS.pack reqPath

-- |>>> trim "  ab c d "
-- "ab c d"
trim ∷ String → String
trim = reverse ∘ f ∘ reverse ∘ f
    where
      f = dropWhile isSpace

-- |Convert a 'CIAscii' to an 'Exp' representing it as a literal.
liftCIAscii ∷ CIAscii → Q Exp
liftCIAscii a = [| A.toCIAscii (A.unsafeFromString $(strLit a)) |]
    where
      strLit ∷ CIAscii → Q Exp
      strLit = liftString ∘ A.toString ∘ A.fromCIAscii

-- |Convert a 'Text' to an 'Exp' representing it as a literal.
liftText ∷ Text → Q Exp
liftText t = [| T.pack $(strLit t) |]
    where
      strLit ∷ Text → Q Exp
      strLit = liftString ∘ T.unpack

-- |Convert an arbitrary 'Map' to an 'Exp' representing it as a
-- literal, using a given key lifter and a value lifter.
liftMap ∷ Eq k ⇒ (k → Q Exp) → (v → Q Exp) → Map k v → Q Exp
liftMap liftK liftV m = [| M.fromAscList $(liftPairs $ M.toAscList m) |]
    where
      liftPairs       = listE ∘ map liftPair
      liftPair (k, v) = tupE [liftK k, liftV v]