Data/Time/RFC733.hs

   1 {-# LANGUAGE
   2     FlexibleInstances
   3   , MultiParamTypeClasses
   4   , OverloadedStrings
   5   , TemplateHaskell
   6   , UnicodeSyntax
   7   #-}
   8 -- |This module provides functions to parse and format RFC 733 date
   9 -- and time formats.
  10 --
  11 -- The syntax is as follows:
  12 --
  13 -- > date-time   ::= [ day-of-week ", " ] date SP time ("-" | SP) zone
  14 -- > day-of-week ::= "Monday"    | "Mon" | "Tuesday"  | "Tue"
  15 -- >               | "Wednesday" | "Wed" | "Thursday" | "Thu"
  16 -- >               | "Friday"    | "Fri" | "Saturday" | "Sat"
  17 -- >               | "Sunday"    | "Sun"
  18 -- > date        ::= day ("-" | SP) month ("-" | SP) year
  19 -- > day         ::= 2DIGIT
  20 -- > year        ::= 2DIGIT | 4DIGIT
  21 -- > month       ::= "January"   | "Jan" | "February" | "Feb"
  22 -- >               | "March"     | "Mar" | "April"    | "Apr"
  23 -- >               | "May"               | "June"     | "Jun"
  24 -- >               | "July"      | "Jul" | "August"   | "Aug"
  25 -- >               | "September" | "Sep" | "October"  | "Oct"
  26 -- >               | "November"  | "Nov" | "December" | "Dec"
  27 -- > time        ::= hour [ ":" ] minute [ [ ":" ] second ]
  28 -- > hour        ::= 2DIGIT
  29 -- > minute      ::= 2DIGIT
  30 -- > second      ::= 2DIGIT
  31 -- > zone        ::= "GMT"              ; Universal Time
  32 -- >               | "NST"              ; Newfoundland: -3:30
  33 -- >               | "AST" | "ADT"      ; Atlantic    :  -4 /  -3
  34 -- >               | "EST" | "EDT"      ; Eastern     :  -5 /  -4
  35 -- >               | "CST" | "CDT"      ; Central     :  -6 /  -5
  36 -- >               | "MST" | "MDT"      ; Mountain    :  -7 /  -6
  37 -- >               | "PST" | "PDT"      ; Pacific     :  -8 /  -7
  38 -- >               | "YST" | "YDT"      ; Yukon       :  -9 /  -8
  39 -- >               | "HST" | "HDT"      ; Haw/Ala     : -10 /  -9
  40 -- >               | "BST" | "BDT"      ; Bering      : -11 / -10
  41 -- >               | "Z"                ; GMT
  42 -- >               | "A"                ;  -1
  43 -- >               | "M"                ; -12
  44 -- >               | "N"                ;  +1
  45 -- >               | "Y"                ; +12
  46 -- >               | ("+" | "-") 4DIGIT ; Local diff: HHMM
  47 module Data.Time.RFC733
  48     ( RFC733
  49     , rfc733DateAndTime
  50     )
  51     where
  52 import Control.Applicative
  53 import Data.Ascii (Ascii, AsciiBuilder)
  54 import qualified Data.Ascii as A
  55 import Data.Attoparsec.Char8
  56 import Data.Convertible.Base
  57 import Data.Monoid.Unicode
  58 import Data.Tagged
  59 import Data.Time
  60 import Data.Time.Calendar.WeekDate
  61 import Data.Time.RFC822
  62 import Data.Time.HTTP.Common
  63 import Prelude.Unicode
  64
  65 -- FIXME: docs
  66 data RFC733
  67
  68 instance ConvertSuccess ZonedTime (Tagged RFC733 Ascii) where
  69     {-# INLINE convertSuccess #-}
  70     convertSuccess = (A.fromAsciiBuilder <$>) ∘ cs
  71
  72 instance ConvertSuccess ZonedTime (Tagged RFC733 AsciiBuilder) where
  73     {-# INLINE convertSuccess #-}
  74     convertSuccess = Tagged ∘ toAsciiBuilder
  75
  76 instance ConvertAttempt (Tagged RFC733 Ascii) ZonedTime where
  77     {-# INLINE convertAttempt #-}
  78     convertAttempt = parseAttempt' rfc733DateAndTime ∘ untag
  79
  80 rfc733DateAndTime ∷ Parser ZonedTime
  81 rfc733DateAndTime = dateTime
  82
  83 dateTime ∷ Parser ZonedTime
  84 dateTime = do weekDay ← optionMaybe $
  85                         do w ← longWeekDayNameP
  86                                <|>
  87                                shortWeekDayNameP
  88                            _ ← string ", "
  89                            return w
  90               gregDay ← date
  91               case weekDay of
  92                 Nothing
  93                     → return ()
  94                 Just givenWD
  95                     → assertWeekDayIsGood givenWD gregDay
  96               (tod, timeZone) ← time
  97               let lt = LocalTime gregDay tod
  98                   zt = ZonedTime lt timeZone
  99               return zt
 100
 101 date ∷ Parser Day
 102 date = do day   ← read2
 103           _     ← char '-' <|> char ' '
 104           month ← try longMonthNameP
 105                   <|>
 106                   shortMonthNameP
 107           _     ← char '-' <|> char ' '
 108           year  ← try read4
 109                   <|>
 110                   (+ 1900) <$> read2
 111           _     ← char ' '
 112           assertGregorianDateIsGood year month day
 113
 114 time ∷ Parser (TimeOfDay, TimeZone)
 115 time = do tod ← hms
 116           _   ← char '-' <|> char ' '
 117           tz  ← zone
 118           return (tod, tz)
 119
 120 hms ∷ Parser TimeOfDay
 121 hms = do hour   ← read2
 122          _      ← optional (char ':')
 123          minute ← read2
 124          second ← option 0 $
 125                   do _ ← optional (char ':')
 126                      read2
 127          assertTimeOfDayIsGood hour minute second
 128
 129 zone ∷ Parser TimeZone
 130 zone = choice [ string "GMT" *> return (TimeZone 0 False "GMT")
 131               , char 'N'
 132                 *> choice [ string "ST" *> return (TimeZone ((-3) * 60 - 30) False "NST")
 133                           , return (TimeZone (1 * 60) False "N")
 134                           ]
 135               , char 'A'
 136                 *> choice [ string "ST" *> return (TimeZone ((-4) * 60) False "AST")
 137                           , string "DT" *> return (TimeZone ((-3) * 60) False "AST")
 138                           , return (TimeZone ((-1) * 60) False "A")
 139                           ]
 140               , char 'E'
 141                 *> choice [ string "ST" *> return (TimeZone ((-5) * 60) False "EST")
 142                           , string "DT" *> return (TimeZone ((-4) * 60) True  "EDT")
 143                           ]
 144               , char 'C'
 145                 *> choice [ string "ST" *> return (TimeZone ((-6) * 60) False "CST")
 146                           , string "DT" *> return (TimeZone ((-5) * 60) True  "CDT")
 147                           ]
 148               , char 'M'
 149                 *> choice [ string "ST" *> return (TimeZone ((-7) * 60) False "MST")
 150                           , string "DT" *> return (TimeZone ((-6) * 60) True  "MDT")
 151                           , return (TimeZone ((-12) * 60) False "M")
 152                           ]
 153               , char 'P'
 154                 *> choice [ string "ST" *> return (TimeZone ((-8) * 60) False "PST")
 155                           , string "DT" *> return (TimeZone ((-7) * 60) True  "PDT")
 156                           ]
 157               , char 'Y'
 158                 *> choice [ string "ST" *> return (TimeZone ((-9) * 60) False "YST")
 159                           , string "DT" *> return (TimeZone ((-8) * 60) True  "YDT")
 160                           , return (TimeZone ( 12  * 60) False "Y")
 161                           ]
 162               , char 'H'
 163                 *> choice [ string "ST" *> return (TimeZone ((-10) * 60) False "HST")
 164                           , string "DT" *> return (TimeZone (( -9) * 60) True  "HDT")
 165                           ]
 166               , char 'B'
 167                 *> choice [ string "ST" *> return (TimeZone ((-11) * 60) False "BST")
 168                           , string "DT" *> return (TimeZone ((-10) * 60) True  "BDT")
 169                           ]
 170               , char 'Z' *> return (TimeZone 0 False "Z")
 171               , read4digitsTZ
 172               ]
 173
 174 toAsciiBuilder ∷ ZonedTime → AsciiBuilder
 175 toAsciiBuilder zonedTime
 176     = let localTime          = zonedTimeToLocalTime zonedTime
 177           timeZone           = zonedTimeZone zonedTime
 178           (year, month, day) = toGregorian (localDay localTime)
 179           (_, _, week)       = toWeekDate  (localDay localTime)
 180           timeOfDay          = localTimeOfDay localTime
 181       in
 182         longWeekDayName week
 183         ⊕ A.toAsciiBuilder ", "
 184         ⊕ show2 day
 185         ⊕ A.toAsciiBuilder "-"
 186         ⊕ shortMonthName month
 187         ⊕ A.toAsciiBuilder "-"
 188         ⊕ show4 year
 189         ⊕ A.toAsciiBuilder " "
 190         ⊕ show2 (todHour timeOfDay)
 191         ⊕ A.toAsciiBuilder ":"
 192         ⊕ show2 (todMin timeOfDay)
 193         ⊕ A.toAsciiBuilder ":"
 194         ⊕ show2 (floor (todSec timeOfDay) ∷ Int)
 195         ⊕ A.toAsciiBuilder " "
 196         ⊕ untag (cs timeZone ∷ Tagged RFC822 AsciiBuilder)
 197
 198 deriveAttempts [ ([t| ZonedTime |], [t| Tagged RFC733 Ascii        |])
 199                , ([t| ZonedTime |], [t| Tagged RFC733 AsciiBuilder |])
 200                ]