Data/Time/RFC733.hs

   1 -- |This module provides functions to parse and format RFC 733 date
   2 -- and time formats.
   3 --
   4 -- The syntax is as follows:
   5 --
   6 -- > date-time   ::= [ day-of-week ", " ] date SP time ("-" | SP) zone
   7 -- > day-of-week ::= "Monday"    | "Mon" | "Tuesday"  | "Tue"
   8 -- >               | "Wednesday" | "Wed" | "Thursday" | "Thu"
   9 -- >               | "Friday"    | "Fri" | "Saturday" | "Sat"
  10 -- >               | "Sunday"    | "Sun"
  11 -- > date        ::= day ("-" | SP) month ("-" | SP) year
  12 -- > day         ::= 2DIGIT
  13 -- > year        ::= 2DIGIT | 4DIGIT
  14 -- > month       ::= "January"   | "Jan" | "February" | "Feb"
  15 -- >               | "March"     | "Mar" | "April"    | "Apr"
  16 -- >               | "May"               | "June"     | "Jun"
  17 -- >               | "July"      | "Jul" | "August"   | "Aug"
  18 -- >               | "September" | "Sep" | "October"  | "Oct"
  19 -- >               | "November"  | "Nov" | "December" | "Dec"
  20 -- > time        ::= hour [ ":" ] minute [ [ ":" ] second ]
  21 -- > hour        ::= 2DIGIT
  22 -- > minute      ::= 2DIGIT
  23 -- > second      ::= 2DIGIT
  24 -- > zone        ::= "GMT"              ; Universal Time
  25 -- >               | "NST"              ; Newfoundland: -3:30
  26 -- >               | "AST" | "ADT"      ; Atlantic    :  -4 /  -3
  27 -- >               | "EST" | "EDT"      ; Eastern     :  -5 /  -4
  28 -- >               | "CST" | "CDT"      ; Central     :  -6 /  -5
  29 -- >               | "MST" | "MDT"      ; Mountain    :  -7 /  -6
  30 -- >               | "PST" | "PDT"      ; Pacific     :  -8 /  -7
  31 -- >               | "YST" | "YDT"      ; Yukon       :  -9 /  -8
  32 -- >               | "HST" | "HDT"      ; Haw/Ala     : -10 /  -9
  33 -- >               | "BST" | "BDT"      ; Bering      : -11 / -10
  34 -- >               | "Z"                ; GMT
  35 -- >               | "A"                ;  -1
  36 -- >               | "M"                ; -12
  37 -- >               | "N"                ;  +1
  38 -- >               | "Y"                ; +12
  39 -- >               | ("+" | "-") 4DIGIT ; Local diff: HHMM
  40 module Data.Time.RFC733
  41     ( format
  42     , parse
  43     )
  44     where
  45
  46 import qualified Text.Parsec as P
  47
  48 import Data.Time
  49 import Data.Time.Calendar.WeekDate
  50 import Data.Time.HTTP.Common
  51 import Data.Time.RFC733.Parsec
  52
  53 -- |Format a 'ZonedTime' in RFC 733.
  54 format :: ZonedTime -> String
  55 format zonedTime
  56     = let localTime          = zonedTimeToLocalTime zonedTime
  57           timeZone           = zonedTimeZone zonedTime
  58           (year, month, day) = toGregorian (localDay localTime)
  59           (_, _, week)       = toWeekDate  (localDay localTime)
  60           timeOfDay          = localTimeOfDay localTime
  61       in
  62         concat [ longWeekDayName week
  63                , ", "
  64                , show2 day
  65                , "-"
  66                , shortMonthName month
  67                , "-"
  68                , show4 year
  69                , " "
  70                , show2 (todHour timeOfDay)
  71                , ":"
  72                , show2 (todMin timeOfDay)
  73                , ":"
  74                , show2 (floor (todSec timeOfDay))
  75                , "-"
  76                , show4digitsTZ timeZone
  77                ]
  78
  79 -- |Parse an RFC 733 date and time string. When the string can't be
  80 -- parsed, it returns 'Nothing'.
  81 parse :: String -> Maybe ZonedTime
  82 parse src = case P.parse p "" src of
  83               Right zt -> Just zt
  84               Left  _  -> Nothing
  85     where
  86       p = do zt <- rfc733DateAndTime
  87              _  <- P.eof
  88              return zt