module Data.Time.RFC822
    ( format
    , parse

    -- private
    , showRFC822TimeZone
    )
    where

import qualified Text.Parsec as P

import Data.Time
import Data.Time.Calendar.WeekDate
import Data.Time.HTTP.Common
import Data.Time.RFC822.Parsec


{-
     date-time   =  [ day "," ] date time        ; dd mm yy
                                                 ;  hh:mm:ss zzz

     day         =  "Mon"  / "Tue" /  "Wed"  / "Thu"
                 /  "Fri"  / "Sat" /  "Sun"

     date        =  1*2DIGIT month 2DIGIT        ; day month year
                                                 ;  e.g. 20 Jun 82

     month       =  "Jan"  /  "Feb" /  "Mar"  /  "Apr"
                 /  "May"  /  "Jun" /  "Jul"  /  "Aug"
                 /  "Sep"  /  "Oct" /  "Nov"  /  "Dec"

     time        =  hour zone                    ; ANSI and Military

     hour        =  2DIGIT ":" 2DIGIT [":" 2DIGIT]
                                                 ; 00:00:00 - 23:59:59

     zone        =  "UT"  / "GMT"                ; Universal Time
                                                 ; North American : UT
                 /  "EST" / "EDT"                ;  Eastern:  - 5/ - 4
                 /  "CST" / "CDT"                ;  Central:  - 6/ - 5
                 /  "MST" / "MDT"                ;  Mountain: - 7/ - 6
                 /  "PST" / "PDT"                ;  Pacific:  - 8/ - 7
                 /  1ALPHA                       ; Military: Z = UT;
                                                 ;  A:-1; (J not used)
                                                 ;  M:-12; N:+1; Y:+12
                 / ( ("+" / "-") 4DIGIT )        ; Local differential
                                                 ;  hours+min. (HHMM)
-}

format :: ZonedTime -> String
format zonedTime
    = let localTime          = zonedTimeToLocalTime zonedTime
          timeZone           = zonedTimeZone zonedTime
          (year, month, day) = toGregorian (localDay localTime)
          (_, _, week)       = toWeekDate  (localDay localTime)
          timeOfDay          = localTimeOfDay localTime
      in
        concat [ shortWeekDayName week
               , ", "
               , show2 day
               , " "
               , shortMonthName month
               , " "
               , show2 (year `mod` 100)
               , " "
               , show2 (todHour timeOfDay)
               , ":"
               , show2 (todMin timeOfDay)
               , ":"
               , show2 (floor (todSec timeOfDay))
               , " "
               , showRFC822TimeZone timeZone
               ]

showRFC822TimeZone :: TimeZone -> String
showRFC822TimeZone tz
    | timeZoneMinutes tz == 0 = "GMT"
    | otherwise               = show4digitsTZ tz

parse :: String -> Maybe ZonedTime
parse src = case P.parse p "" src of
              Right zt -> Just zt
              Left  _  -> Nothing
    where
      p = do zt <- rfc822DateAndTime
             _  <- P.eof
             return zt