Codec/Audio/WavPack/Internal.hs

   1 {-# LANGUAGE
   2     BangPatterns
   3   , UnicodeSyntax
   4   #-}
   5 -- | WavPack internal functions
   6 module Codec.Audio.WavPack.Internal
   7     ( packWeight
   8     , unpackWeight
   9
  10     , log2s
  11     , log2
  12
  13     , exp2s
  14     , exp2
  15
  16     , countBits
  17
  18     , b2n
  19     )
  20     where
  21 import Data.Int
  22 import Data.Word
  23 import Data.Bits
  24 import qualified Data.Vector.Unboxed as UV
  25 import Prelude.Unicode
  26
  27 -- | Convert internal weights (which are normally +/-1024) to an 8-bit
  28 -- signed character version for storage in metadata. The weights are
  29 -- clipped here in the case they are outside that range.
  30 packWeight ∷ Int16 → Word8
  31 {-# INLINEABLE packWeight #-}
  32 packWeight !w
  33     = let !w'   | w  >  1024 =  1024
  34                 | w  < -1024 = -1024
  35                 | otherwise  =     w
  36           !w''  | w' >     0 = w' - ((w' + 64) `shiftR` 7)
  37                 | otherwise  = w'
  38           !w'''              = (w'' + 4) `shiftR` 3
  39       in
  40         fromIntegral w'''
  41
  42 -- | Convert a packed weight to internal weight (+/-1024). Note that
  43 -- the following equation /might not hold/ because 'packWeight' is
  44 -- lossy.
  45 --
  46 -- > unpackWeight . packWeight = id
  47 --
  48 unpackWeight ∷ Word8 → Int16
  49 {-# INLINEABLE unpackWeight #-}
  50 unpackWeight !w
  51     = let w'  ∷ Int8
  52           w'  = fromIntegral w
  53           w'' ∷ Int16
  54           w'' = (fromIntegral w') `shiftL` 3
  55           !w''' | w'' > 0   = w'' + ((w'' + 64) `shiftR` 7)
  56                 | otherwise = w''
  57       in
  58         w'''
  59
  60 -- | Return the 'log2' for the specified 32-bit signed integer. All
  61 -- input values are valid and the return values are in the range of
  62 -- +/-8192.
  63 log2s ∷ Int32 → Int16
  64 {-# INLINE log2s #-}
  65 log2s !n
  66     | n < 0     = fromIntegral $ negate $ log2 $ fromIntegral $ negate n
  67     | otherwise = fromIntegral $ log2 $ fromIntegral n
  68
  69 -- | The concept of a base 2 logarithm is used in many parts of
  70 -- WavPack. It is a way of sufficiently accurately representing 32-bit
  71 -- signed and unsigned values storing only 16 bits (actually
  72 -- fewer). It is also used in the hybrid mode for quickly comparing
  73 -- the relative magnitude of large values (i.e.  division) and
  74 -- providing smooth exponentials using only addition.
  75 --
  76 -- These are not strict logarithms in that they become linear around
  77 -- zero and can therefore represent both zero and negative
  78 -- values. They have 8 bits of precision and in \"roundtrip\"
  79 -- conversions the total error never exceeds 1 part in 225 except for
  80 -- the cases of +\/-115 and +\/-195 (which error by 1).
  81 --
  82 -- This function returns the log2 for the specified 32-bit unsigned
  83 -- value. The maximum value allowed is about 0xff800000 and returns
  84 -- 8447.
  85 log2 ∷ Word32 → Word16
  86 {-# INLINEABLE log2 #-}
  87 log2 !n
  88     | n' < (1 `shiftL` 8)
  89         = let dbits  ∷ Word16
  90               !dbits = getNBits $ fromIntegral n'
  91               !index = (n' `shiftL` fromIntegral (9 - dbits)) .&. 0xFF
  92               !log2n = getLog2 $ fromIntegral index
  93           in
  94             (dbits `shiftL` 8) + log2n
  95     | otherwise
  96         = let dbits ∷ Word16
  97               !dbits | n' < (1 `shiftL` 16)
  98                          = (getNBits $ fromIntegral $ n' `shiftR`  8) +  8
  99                      | n' < (1 `shiftL` 24)
 100                          = (getNBits $ fromIntegral $ n' `shiftR` 16) + 16
 101                      | otherwise
 102                          = (getNBits $ fromIntegral $ n' `shiftR` 24) + 24
 103               !index = (n' `shiftR` fromIntegral (dbits - 9)) .&. 0xFF
 104               !log2n = getLog2 $ fromIntegral index
 105           in
 106             (dbits `shiftL` 8) + log2n
 107     where
 108       n' ∷ Word32
 109       n' = n + (n `shiftR` 9)
 110
 111 -- | Return the original integer represented by the supplied logarithm
 112 -- (at least within the provided accuracy). The log is signed, but
 113 -- since a full 32-bit value is returned this can be used for unsigned
 114 -- conversions as well (i.e. the input range is -8192 to +8447).
 115 exp2s ∷ Int16 → Int32
 116 {-# INLINE exp2s #-}
 117 exp2s !l
 118     | l < 0     = fromIntegral $ negate $ exp2 $ fromIntegral $ negate l
 119     | otherwise = fromIntegral $ exp2 $ fromIntegral l
 120
 121 -- | Return the original integer represented by the supplied logarithm
 122 -- (at least within the provided accuracy).
 123 exp2 ∷ Word16 → Word32
 124 {-# INLINEABLE exp2 #-}
 125 exp2 !l
 126     = let exp2l ∷ Word32
 127           exp2l = (getExp2 $ fromIntegral $ l .&. 0xFF) .|. 0x100
 128           l'    ∷ Word32
 129           l'    = fromIntegral $ l `shiftR` 8
 130       in
 131         if l' ≤ 9 then
 132             exp2l `shiftR` fromIntegral (9 - l')
 133         else
 134             exp2l `shiftL` fromIntegral (l' - 9)
 135
 136 -- | 'countBits' @av@ returns the number of bits that is required to
 137 -- represent @av@.
 138 countBits ∷ Num a ⇒ Word32 → a
 139 {-# INLINEABLE countBits #-}
 140 countBits av
 141     | av < (1 `shiftL`  8) = getNBits (fromIntegral  av)
 142     | av < (1 `shiftL` 16) = getNBits (fromIntegral (av `shiftR`  8)) +  8
 143     | av < (1 `shiftL` 24) = getNBits (fromIntegral (av `shiftR` 16)) + 16
 144     | otherwise            = getNBits (fromIntegral (av `shiftR` 24)) + 24
 145
 146 -- | Return 0 for 'False' and 1 for 'True'.
 147 b2n ∷ Num a ⇒ Bool → a
 148 {-# INLINE b2n #-}
 149 b2n True  = 1
 150 b2n False = 0
 151
 152 getNBits ∷ Num a ⇒ Word8 → a
 153 {-# INLINE getNBits #-}
 154 getNBits = fromIntegral ∘ UV.unsafeIndex nbitsTable ∘ fromIntegral
 155     where
 156       nbitsTable ∷ UV.Vector Word8
 157       nbitsTable
 158           = UV.fromList
 159             [ 0, 1, 2, 2, 3, 3, 3, 3, 4, 4, 4, 4, 4, 4, 4, 4 --   0 -  15
 160             , 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5 --  16 -  31
 161             , 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6 --  32 -  47
 162             , 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6 --  48 -  63
 163             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 --  64 -  79
 164             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 --  80 -  95
 165             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 --  96 - 111
 166             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 -- 112 - 127
 167             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 128 - 143
 168             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 144 - 159
 169             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 160 - 175
 170             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 176 - 191
 171             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 192 - 207
 172             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 208 - 223
 173             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 224 - 239
 174             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 240 - 255
 175             ]
 176
 177 getLog2 ∷ Num n ⇒ Word8 → n
 178 {-# INLINE getLog2 #-}
 179 getLog2 = fromIntegral ∘ UV.unsafeIndex log2Table ∘ fromIntegral
 180     where
 181       log2Table ∷ UV.Vector Word8
 182       log2Table
 183           = UV.fromList
 184             [ 0x00, 0x01, 0x03, 0x04, 0x06, 0x07, 0x09, 0x0a, 0x0B, 0x0D, 0x0E, 0x10, 0x11, 0x12, 0x14, 0x15
 185             , 0x16, 0x18, 0x19, 0x1a, 0x1C, 0x1D, 0x1E, 0x20, 0x21, 0x22, 0x24, 0x25, 0x26, 0x28, 0x29, 0x2a
 186             , 0x2C, 0x2D, 0x2E, 0x2F, 0x31, 0x32, 0x33, 0x34, 0x36, 0x37, 0x38, 0x39, 0x3B, 0x3C, 0x3D, 0x3E
 187             , 0x3F, 0x41, 0x42, 0x43, 0x44, 0x45, 0x47, 0x48, 0x49, 0x4a, 0x4B, 0x4D, 0x4E, 0x4F, 0x50, 0x51
 188             , 0x52, 0x54, 0x55, 0x56, 0x57, 0x58, 0x59, 0x5a, 0x5C, 0x5D, 0x5E, 0x5F, 0x60, 0x61, 0x62, 0x63
 189             , 0x64, 0x66, 0x67, 0x68, 0x69, 0x6a, 0x6B, 0x6C, 0x6D, 0x6E, 0x6F, 0x70, 0x71, 0x72, 0x74, 0x75
 190             , 0x76, 0x77, 0x78, 0x79, 0x7a, 0x7B, 0x7C, 0x7D, 0x7E, 0x7F, 0x80, 0x81, 0x82, 0x83, 0x84, 0x85
 191             , 0x86, 0x87, 0x88, 0x89, 0x8a, 0x8B, 0x8C, 0x8D, 0x8E, 0x8F, 0x90, 0x91, 0x92, 0x93, 0x94, 0x95
 192             , 0x96, 0x97, 0x98, 0x99, 0x9a, 0x9B, 0x9B, 0x9C, 0x9D, 0x9E, 0x9F, 0xa0, 0xa1, 0xa2, 0xa3, 0xa4
 193             , 0xa5, 0xa6, 0xa7, 0xa8, 0xa9, 0xa9, 0xaa, 0xaB, 0xaC, 0xaD, 0xaE, 0xaF, 0xB0, 0xB1, 0xB2, 0xB2
 194             , 0xB3, 0xB4, 0xB5, 0xB6, 0xB7, 0xB8, 0xB9, 0xB9, 0xBa, 0xBB, 0xBC, 0xBD, 0xBE, 0xBF, 0xC0, 0xC0
 195             , 0xC1, 0xC2, 0xC3, 0xC4, 0xC5, 0xC6, 0xC6, 0xC7, 0xC8, 0xC9, 0xCa, 0xCB, 0xCB, 0xCC, 0xCD, 0xCE
 196             , 0xCF, 0xD0, 0xD0, 0xD1, 0xD2, 0xD3, 0xD4, 0xD4, 0xD5, 0xD6, 0xD7, 0xD8, 0xD8, 0xD9, 0xDa, 0xDB
 197             , 0xDC, 0xDC, 0xDD, 0xDE, 0xDF, 0xE0, 0xE0, 0xE1, 0xE2, 0xE3, 0xE4, 0xE4, 0xE5, 0xE6, 0xE7, 0xE7
 198             , 0xE8, 0xE9, 0xEa, 0xEa, 0xEB, 0xEC, 0xED, 0xEE, 0xEE, 0xEF, 0xF0, 0xF1, 0xF1, 0xF2, 0xF3, 0xF4
 199             , 0xF4, 0xF5, 0xF6, 0xF7, 0xF7, 0xF8, 0xF9, 0xF9, 0xFa, 0xFB, 0xFC, 0xFC, 0xFD, 0xFE, 0xFF, 0xFF
 200             ]
 201
 202 getExp2 ∷ Num n ⇒ Word8 → n
 203 {-# INLINE getExp2 #-}
 204 getExp2 = fromIntegral ∘ UV.unsafeIndex exp2Table ∘ fromIntegral
 205     where
 206       exp2Table ∷ UV.Vector Word8
 207       exp2Table
 208           = UV.fromList
 209             [ 0x00, 0x01, 0x01, 0x02, 0x03, 0x03, 0x04, 0x05, 0x06, 0x06, 0x07, 0x08, 0x08, 0x09, 0x0a, 0x0B
 210             , 0x0B, 0x0C, 0x0D, 0x0E, 0x0E, 0x0F, 0x10, 0x10, 0x11, 0x12, 0x13, 0x13, 0x14, 0x15, 0x16, 0x16
 211             , 0x17, 0x18, 0x19, 0x19, 0x1a, 0x1B, 0x1C, 0x1D, 0x1D, 0x1E, 0x1F, 0x20, 0x20, 0x21, 0x22, 0x23
 212             , 0x24, 0x24, 0x25, 0x26, 0x27, 0x28, 0x28, 0x29, 0x2a, 0x2B, 0x2C, 0x2C, 0x2D, 0x2E, 0x2F, 0x30
 213             , 0x30, 0x31, 0x32, 0x33, 0x34, 0x35, 0x35, 0x36, 0x37, 0x38, 0x39, 0x3a, 0x3a, 0x3B, 0x3C, 0x3D
 214             , 0x3E, 0x3F, 0x40, 0x41, 0x41, 0x42, 0x43, 0x44, 0x45, 0x46, 0x47, 0x48, 0x48, 0x49, 0x4a, 0x4B
 215             , 0x4C, 0x4D, 0x4E, 0x4F, 0x50, 0x51, 0x51, 0x52, 0x53, 0x54, 0x55, 0x56, 0x57, 0x58, 0x59, 0x5a
 216             , 0x5B, 0x5C, 0x5D, 0x5E, 0x5E, 0x5F, 0x60, 0x61, 0x62, 0x63, 0x64, 0x65, 0x66, 0x67, 0x68, 0x69
 217             , 0x6a, 0x6B, 0x6C, 0x6D, 0x6E, 0x6F, 0x70, 0x71, 0x72, 0x73, 0x74, 0x75, 0x76, 0x77, 0x78, 0x79
 218             , 0x7a, 0x7B, 0x7C, 0x7D, 0x7E, 0x7F, 0x80, 0x81, 0x82, 0x83, 0x84, 0x85, 0x87, 0x88, 0x89, 0x8a
 219             , 0x8B, 0x8C, 0x8D, 0x8E, 0x8F, 0x90, 0x91, 0x92, 0x93, 0x95, 0x96, 0x97, 0x98, 0x99, 0x9a, 0x9B
 220             , 0x9C, 0x9D, 0x9F, 0xa0, 0xa1, 0xa2, 0xa3, 0xa4, 0xa5, 0xa6, 0xa8, 0xa9, 0xaa, 0xaB, 0xaC, 0xaD
 221             , 0xaF, 0xB0, 0xB1, 0xB2, 0xB3, 0xB4, 0xB6, 0xB7, 0xB8, 0xB9, 0xBa, 0xBC, 0xBD, 0xBE, 0xBF, 0xC0
 222             , 0xC2, 0xC3, 0xC4, 0xC5, 0xC6, 0xC8, 0xC9, 0xCa, 0xCB, 0xCD, 0xCE, 0xCF, 0xD0, 0xD2, 0xD3, 0xD4
 223             , 0xD6, 0xD7, 0xD8, 0xD9, 0xDB, 0xDC, 0xDD, 0xDE, 0xE0, 0xE1, 0xE2, 0xE4, 0xE5, 0xE6, 0xE8, 0xE9
 224             , 0xEa, 0xEC, 0xED, 0xEE, 0xF0, 0xF1, 0xF2, 0xF4, 0xF5, 0xF6, 0xF8, 0xF9, 0xFa, 0xFC, 0xFD, 0xFF
 225             ]