Codec/Audio/WavPack/Internal.hs

   1 {-# LANGUAGE
   2     BangPatterns
   3   , UnicodeSyntax
   4   #-}
   5 -- | WavPack internal functions
   6 module Codec.Audio.WavPack.Internal
   7     ( packWeight
   8     , unpackWeight
   9
  10     , log2s
  11     , log2
  12
  13     , exp2s
  14     , exp2
  15     )
  16     where
  17 import Data.Int
  18 import Data.Word
  19 import Data.Bits
  20 import qualified Data.Vector.Unboxed as UV
  21 import Prelude.Unicode
  22
  23 -- | Convert internal weights (which are normally +/-1024) to an 8-bit
  24 -- signed character version for storage in metadata. The weights are
  25 -- clipped here in the case they are outside that range.
  26 packWeight ∷ Int16 → Word8
  27 packWeight !w
  28     = let !w'   | w  >  1024 =  1024
  29                 | w  < -1024 = -1024
  30                 | otherwise  =     w
  31           !w''  | w' >     0 = w' - ((w' + 64) `shiftR` 7)
  32                 | otherwise  = w'
  33           !w'''              = (w'' + 4) `shiftR` 3
  34       in
  35         fromIntegral w'''
  36
  37 -- | Convert a packed weight to internal weight (+/-1024). Note that
  38 -- the following equation might not hold because 'packWeight' is
  39 -- lossy.
  40 --
  41 -- > unpackWeight . packWeight = id
  42 --
  43 unpackWeight ∷ Word8 → Int16
  44 unpackWeight !w
  45     = let w'  ∷ Int8
  46           w'  = fromIntegral w
  47           w'' ∷ Int16
  48           w'' = (fromIntegral w') `shiftL` 3
  49           !w''' | w'' > 0   = w'' + ((w'' + 64) `shiftR` 7)
  50                 | otherwise = w''
  51       in
  52         w'''
  53
  54 -- | Return the 'log2' for the specified 32-bit signed integer. All
  55 -- input values are valid and the return values are in the range of
  56 -- +/-8192.
  57 log2s ∷ Int32 → Int16
  58 log2s !n
  59     | n < 0     = fromIntegral $ negate $ log2 $ fromIntegral $ negate n
  60     | otherwise = fromIntegral $ log2 $ fromIntegral n
  61
  62 -- | The concept of a base 2 logarithm is used in many parts of
  63 -- WavPack. It is a way of sufficiently accurately representing 32-bit
  64 -- signed and unsigned values storing only 16 bits (actually
  65 -- fewer). It is also used in the hybrid mode for quickly comparing
  66 -- the relative magnitude of large values (i.e.  division) and
  67 -- providing smooth exponentials using only addition.
  68 --
  69 -- These are not strict logarithms in that they become linear around
  70 -- zero and can therefore represent both zero and negative
  71 -- values. They have 8 bits of precision and in \"roundtrip\"
  72 -- conversions the total error never exceeds 1 part in 225 except for
  73 -- the cases of +/-115 and +/-195 (which error by 1).
  74 --
  75 -- This function returns the log2 for the specified 32-bit unsigned
  76 -- value. The maximum value allowed is about 0xff800000 and returns
  77 -- 8447.
  78 log2 ∷ Word32 → Word16
  79 log2 !n
  80     | n' < (1 `shiftL` 8)
  81         = let dbits  ∷ Word16
  82               dbits  = fromIntegral $ getNBits $ fromIntegral n'
  83               !index = (n' `shiftL` fromIntegral (9 - dbits)) .&. 0xFF
  84               !log2n = fromIntegral $ getLog2 $ fromIntegral index
  85           in
  86             (dbits `shiftL` 8) + log2n
  87     | otherwise
  88         = let dbits ∷ Word16
  89               dbits | n' < (1 `shiftL` 16)
  90                         = fromIntegral (getNBits $ fromIntegral $ n' `shiftR`  8) +  8
  91                     | n' < (1 `shiftL` 24)
  92                         = fromIntegral (getNBits $ fromIntegral $ n' `shiftR` 16) + 16
  93                     | otherwise
  94                         = fromIntegral (getNBits $ fromIntegral $ n' `shiftR` 24) + 24
  95               !index = (n' `shiftR` fromIntegral (dbits - 9)) .&. 0xFF
  96               !log2n = fromIntegral $ getLog2 $ fromIntegral index
  97           in
  98             (dbits `shiftL` 8) + log2n
  99     where
 100       n' ∷ Word32
 101       n' = n + (n `shiftR` 9)
 102
 103 -- | Return the original integer represented by the supplied logarithm
 104 -- (at least within the provided accuracy). The log is signed, but
 105 -- since a full 32-bit value is returned this can be used for unsigned
 106 -- conversions as well (i.e. the input range is -8192 to +8447).
 107 exp2s ∷ Int16 → Int32
 108 exp2s !l
 109     | l < 0     = fromIntegral $ negate $ exp2 $ fromIntegral $ negate l
 110     | otherwise = fromIntegral $ exp2 $ fromIntegral l
 111
 112 -- | Return the original integer represented by the supplied logarithm
 113 -- (at least within the provided accuracy).
 114 exp2 ∷ Word16 → Word32
 115 exp2 !l
 116     = let exp2l ∷ Word32
 117           exp2l = fromIntegral (getExp2 $ fromIntegral $ l .&. 0xFF) .|. 0x100
 118           l'    ∷ Word32
 119           l'    = fromIntegral $ l `shiftR` 8
 120       in
 121         if l' ≤ 9 then
 122             exp2l `shiftR` fromIntegral (9 - l')
 123         else
 124             exp2l `shiftL` fromIntegral (l' - 9)
 125
 126 getNBits ∷ Word8 → Word8
 127 getNBits = UV.unsafeIndex nbitsTable ∘ fromIntegral
 128     where
 129       nbitsTable ∷ UV.Vector Word8
 130       nbitsTable
 131           = UV.fromList
 132             [ 0, 1, 2, 2, 3, 3, 3, 3, 4, 4, 4, 4, 4, 4, 4, 4 --   0 -  15
 133             , 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5, 5 --  16 -  31
 134             , 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6 --  32 -  47
 135             , 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6, 6 --  48 -  63
 136             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 --  64 -  79
 137             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 --  80 -  95
 138             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 --  96 - 111
 139             , 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7, 7 -- 112 - 127
 140             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 128 - 143
 141             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 144 - 159
 142             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 160 - 175
 143             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 176 - 191
 144             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 192 - 207
 145             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 208 - 223
 146             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 224 - 239
 147             , 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8 -- 240 - 255
 148             ]
 149
 150 getLog2 ∷ Word8 → Word8
 151 getLog2 = UV.unsafeIndex log2Table ∘ fromIntegral
 152     where
 153       log2Table ∷ UV.Vector Word8
 154       log2Table
 155           = UV.fromList
 156             [ 0x00, 0x01, 0x03, 0x04, 0x06, 0x07, 0x09, 0x0a, 0x0B, 0x0D, 0x0E, 0x10, 0x11, 0x12, 0x14, 0x15
 157             , 0x16, 0x18, 0x19, 0x1a, 0x1C, 0x1D, 0x1E, 0x20, 0x21, 0x22, 0x24, 0x25, 0x26, 0x28, 0x29, 0x2a
 158             , 0x2C, 0x2D, 0x2E, 0x2F, 0x31, 0x32, 0x33, 0x34, 0x36, 0x37, 0x38, 0x39, 0x3B, 0x3C, 0x3D, 0x3E
 159             , 0x3F, 0x41, 0x42, 0x43, 0x44, 0x45, 0x47, 0x48, 0x49, 0x4a, 0x4B, 0x4D, 0x4E, 0x4F, 0x50, 0x51
 160             , 0x52, 0x54, 0x55, 0x56, 0x57, 0x58, 0x59, 0x5a, 0x5C, 0x5D, 0x5E, 0x5F, 0x60, 0x61, 0x62, 0x63
 161             , 0x64, 0x66, 0x67, 0x68, 0x69, 0x6a, 0x6B, 0x6C, 0x6D, 0x6E, 0x6F, 0x70, 0x71, 0x72, 0x74, 0x75
 162             , 0x76, 0x77, 0x78, 0x79, 0x7a, 0x7B, 0x7C, 0x7D, 0x7E, 0x7F, 0x80, 0x81, 0x82, 0x83, 0x84, 0x85
 163             , 0x86, 0x87, 0x88, 0x89, 0x8a, 0x8B, 0x8C, 0x8D, 0x8E, 0x8F, 0x90, 0x91, 0x92, 0x93, 0x94, 0x95
 164             , 0x96, 0x97, 0x98, 0x99, 0x9a, 0x9B, 0x9B, 0x9C, 0x9D, 0x9E, 0x9F, 0xa0, 0xa1, 0xa2, 0xa3, 0xa4
 165             , 0xa5, 0xa6, 0xa7, 0xa8, 0xa9, 0xa9, 0xaa, 0xaB, 0xaC, 0xaD, 0xaE, 0xaF, 0xB0, 0xB1, 0xB2, 0xB2
 166             , 0xB3, 0xB4, 0xB5, 0xB6, 0xB7, 0xB8, 0xB9, 0xB9, 0xBa, 0xBB, 0xBC, 0xBD, 0xBE, 0xBF, 0xC0, 0xC0
 167             , 0xC1, 0xC2, 0xC3, 0xC4, 0xC5, 0xC6, 0xC6, 0xC7, 0xC8, 0xC9, 0xCa, 0xCB, 0xCB, 0xCC, 0xCD, 0xCE
 168             , 0xCF, 0xD0, 0xD0, 0xD1, 0xD2, 0xD3, 0xD4, 0xD4, 0xD5, 0xD6, 0xD7, 0xD8, 0xD8, 0xD9, 0xDa, 0xDB
 169             , 0xDC, 0xDC, 0xDD, 0xDE, 0xDF, 0xE0, 0xE0, 0xE1, 0xE2, 0xE3, 0xE4, 0xE4, 0xE5, 0xE6, 0xE7, 0xE7
 170             , 0xE8, 0xE9, 0xEa, 0xEa, 0xEB, 0xEC, 0xED, 0xEE, 0xEE, 0xEF, 0xF0, 0xF1, 0xF1, 0xF2, 0xF3, 0xF4
 171             , 0xF4, 0xF5, 0xF6, 0xF7, 0xF7, 0xF8, 0xF9, 0xF9, 0xFa, 0xFB, 0xFC, 0xFC, 0xFD, 0xFE, 0xFF, 0xFF
 172             ]
 173
 174 getExp2 ∷ Word8 → Word8
 175 getExp2 = UV.unsafeIndex exp2Table ∘ fromIntegral
 176     where
 177       exp2Table ∷ UV.Vector Word8
 178       exp2Table
 179           = UV.fromList
 180             [ 0x00, 0x01, 0x01, 0x02, 0x03, 0x03, 0x04, 0x05, 0x06, 0x06, 0x07, 0x08, 0x08, 0x09, 0x0a, 0x0B
 181             , 0x0B, 0x0C, 0x0D, 0x0E, 0x0E, 0x0F, 0x10, 0x10, 0x11, 0x12, 0x13, 0x13, 0x14, 0x15, 0x16, 0x16
 182             , 0x17, 0x18, 0x19, 0x19, 0x1a, 0x1B, 0x1C, 0x1D, 0x1D, 0x1E, 0x1F, 0x20, 0x20, 0x21, 0x22, 0x23
 183             , 0x24, 0x24, 0x25, 0x26, 0x27, 0x28, 0x28, 0x29, 0x2a, 0x2B, 0x2C, 0x2C, 0x2D, 0x2E, 0x2F, 0x30
 184             , 0x30, 0x31, 0x32, 0x33, 0x34, 0x35, 0x35, 0x36, 0x37, 0x38, 0x39, 0x3a, 0x3a, 0x3B, 0x3C, 0x3D
 185             , 0x3E, 0x3F, 0x40, 0x41, 0x41, 0x42, 0x43, 0x44, 0x45, 0x46, 0x47, 0x48, 0x48, 0x49, 0x4a, 0x4B
 186             , 0x4C, 0x4D, 0x4E, 0x4F, 0x50, 0x51, 0x51, 0x52, 0x53, 0x54, 0x55, 0x56, 0x57, 0x58, 0x59, 0x5a
 187             , 0x5B, 0x5C, 0x5D, 0x5E, 0x5E, 0x5F, 0x60, 0x61, 0x62, 0x63, 0x64, 0x65, 0x66, 0x67, 0x68, 0x69
 188             , 0x6a, 0x6B, 0x6C, 0x6D, 0x6E, 0x6F, 0x70, 0x71, 0x72, 0x73, 0x74, 0x75, 0x76, 0x77, 0x78, 0x79
 189             , 0x7a, 0x7B, 0x7C, 0x7D, 0x7E, 0x7F, 0x80, 0x81, 0x82, 0x83, 0x84, 0x85, 0x87, 0x88, 0x89, 0x8a
 190             , 0x8B, 0x8C, 0x8D, 0x8E, 0x8F, 0x90, 0x91, 0x92, 0x93, 0x95, 0x96, 0x97, 0x98, 0x99, 0x9a, 0x9B
 191             , 0x9C, 0x9D, 0x9F, 0xa0, 0xa1, 0xa2, 0xa3, 0xa4, 0xa5, 0xa6, 0xa8, 0xa9, 0xaa, 0xaB, 0xaC, 0xaD
 192             , 0xaF, 0xB0, 0xB1, 0xB2, 0xB3, 0xB4, 0xB6, 0xB7, 0xB8, 0xB9, 0xBa, 0xBC, 0xBD, 0xBE, 0xBF, 0xC0
 193             , 0xC2, 0xC3, 0xC4, 0xC5, 0xC6, 0xC8, 0xC9, 0xCa, 0xCB, 0xCD, 0xCE, 0xCF, 0xD0, 0xD2, 0xD3, 0xD4
 194             , 0xD6, 0xD7, 0xD8, 0xD9, 0xDB, 0xDC, 0xDD, 0xDE, 0xE0, 0xE1, 0xE2, 0xE4, 0xE5, 0xE6, 0xE8, 0xE9
 195             , 0xEa, 0xEC, 0xED, 0xEE, 0xF0, 0xF1, 0xF2, 0xF4, 0xF5, 0xF6, 0xF8, 0xF9, 0xFa, 0xFC, 0xFD, 0xFF
 196             ]