Network/HTTP/Lucu/Headers.hs

   1 {-# LANGUAGE
   2     BangPatterns
   3   , GeneralizedNewtypeDeriving
   4   , OverloadedStrings
   5   , UnicodeSyntax
   6   #-}
   7 module Network.HTTP.Lucu.Headers
   8     ( Headers
   9     , HasHeaders(..)
  10
  11     , toHeaders
  12     , fromHeaders
  13
  14     , headersP
  15     , printHeaders
  16     )
  17     where
  18 import Control.Applicative
  19 import Data.Ascii (Ascii, AsciiBuilder, CIAscii)
  20 import qualified Data.Ascii as A
  21 import Data.Attoparsec.Char8 as P
  22 import qualified Data.ByteString as BS
  23 import Data.Map (Map)
  24 import qualified Data.Map as M
  25 import Data.Monoid
  26 import Data.Monoid.Unicode
  27 import Network.HTTP.Lucu.Parser.Http
  28 import Network.HTTP.Lucu.Utils
  29 import Prelude.Unicode
  30
  31 newtype Headers
  32     = Headers (Map CIAscii Ascii)
  33       deriving (Eq, Show, Monoid)
  34
  35 class HasHeaders a where
  36     getHeaders ∷ a → Headers
  37     setHeaders ∷ a → Headers → a
  38
  39     getHeader ∷ CIAscii → a → Maybe Ascii
  40     {-# INLINE getHeader #-}
  41     getHeader !key !a
  42         = case getHeaders a of
  43             Headers m → M.lookup key m
  44
  45     deleteHeader ∷ CIAscii → a → a
  46     {-# INLINE deleteHeader #-}
  47     deleteHeader !key !a
  48         = case getHeaders a of
  49             Headers m
  50               → setHeaders a $ Headers $ M.delete key m
  51
  52     setHeader ∷ CIAscii → Ascii → a → a
  53     {-# INLINE setHeader #-}
  54     setHeader !key !val !a
  55         = case getHeaders a of
  56             Headers m
  57               → setHeaders a $ Headers $ M.insert key val m
  58
  59 instance HasHeaders Headers where
  60     getHeaders   = id
  61     setHeaders _ = id
  62
  63 toHeaders ∷ [(CIAscii, Ascii)] → Headers
  64 {-# INLINE toHeaders #-}
  65 toHeaders = flip mkHeaders (∅)
  66
  67 mkHeaders ∷ [(CIAscii, Ascii)] → Headers → Headers
  68 mkHeaders []              (Headers m) = Headers m
  69 mkHeaders ((key, val):xs) (Headers m)
  70     = mkHeaders xs $ Headers $
  71       case M.lookup key m of
  72         Nothing  → M.insert key val m
  73         Just old → M.insert key (merge old val) m
  74     where
  75       merge ∷ Ascii → Ascii → Ascii
  76       {-# INLINE merge #-}
  77       merge a b
  78           | nullA a ∧ nullA b = (∅)
  79           | nullA a           = b
  80           |           nullA b = a
  81           | otherwise         = a ⊕ ", " ⊕ b
  82
  83       nullA ∷ Ascii → Bool
  84       {-# INLINE nullA #-}
  85       nullA = BS.null ∘ A.toByteString
  86
  87 fromHeaders ∷ Headers → [(CIAscii, Ascii)]
  88 fromHeaders (Headers m) = M.toList m
  89
  90 {-
  91   message-header = field-name ":" [ field-value ]
  92   field-name     = token
  93   field-value    = *( field-content | LWS )
  94   field-content  = <field-value を構成し、*TEXT あるいは
  95                     token, separators, quoted-string を連結
  96                     したものから成る OCTET>
  97
  98   field-value の先頭および末尾にある LWS は全て削除され、それ以外の
  99   LWS は單一の SP に變換される。
 100 -}
 101 headersP ∷ Parser Headers
 102 {-# INLINEABLE headersP #-}
 103 headersP = do xs ← P.many header
 104               crlf
 105               return $ toHeaders xs
 106     where
 107       header ∷ Parser (CIAscii, Ascii)
 108       header = do name ← A.toCIAscii <$> token
 109                   _    ← char ':'
 110                   skipMany lws
 111                   values ← sepBy content (try lws)
 112                   skipMany (try lws)
 113                   crlf
 114                   return (name, joinValues values)
 115
 116       content ∷ Parser Ascii
 117       {-# INLINE content #-}
 118       content = A.unsafeFromByteString
 119                 <$>
 120                 takeWhile1 (\c → ((¬) (isSPHT c)) ∧ isText c)
 121
 122       joinValues ∷ [Ascii] → Ascii
 123       {-# INLINE joinValues #-}
 124       joinValues = A.fromAsciiBuilder ∘ joinWith "\x20" ∘ map A.toAsciiBuilder
 125
 126 printHeaders ∷ Headers → AsciiBuilder
 127 printHeaders (Headers m)
 128     = mconcat (map printHeader (M.toList m)) ⊕
 129       A.toAsciiBuilder "\x0D\x0A"
 130     where
 131       printHeader ∷ (CIAscii, Ascii) → AsciiBuilder
 132       printHeader (name, value)
 133           = A.toAsciiBuilder (A.fromCIAscii name) ⊕
 134             A.toAsciiBuilder ": "                 ⊕
 135             A.toAsciiBuilder value                ⊕
 136             A.toAsciiBuilder "\x0D\x0A"