Data/Time/Format/RFC733.hs

   1 {-# LANGUAGE
   2     FlexibleInstances
   3   , MultiParamTypeClasses
   4   , OverloadedStrings
   5   , TemplateHaskell
   6   , UnicodeSyntax
   7   #-}
   8 -- |This module provides functions to parse and format RFC 733 date
   9 -- and time strings (<http://tools.ietf.org/html/rfc733#appendix-E>).
  10 --
  11 -- The syntax is as follows:
  12 --
  13 -- > date-time   ::= [ day-of-week ", " ] date SP time ("-" | SP) zone
  14 -- > day-of-week ::= "Monday"    | "Mon" | "Tuesday"  | "Tue"
  15 -- >               | "Wednesday" | "Wed" | "Thursday" | "Thu"
  16 -- >               | "Friday"    | "Fri" | "Saturday" | "Sat"
  17 -- >               | "Sunday"    | "Sun"
  18 -- > date        ::= day ("-" | SP) month ("-" | SP) year
  19 -- > day         ::= 2DIGIT
  20 -- > year        ::= 2DIGIT | 4DIGIT
  21 -- > month       ::= "January"   | "Jan" | "February" | "Feb"
  22 -- >               | "March"     | "Mar" | "April"    | "Apr"
  23 -- >               | "May"               | "June"     | "Jun"
  24 -- >               | "July"      | "Jul" | "August"   | "Aug"
  25 -- >               | "September" | "Sep" | "October"  | "Oct"
  26 -- >               | "November"  | "Nov" | "December" | "Dec"
  27 -- > time        ::= hour [ ":" ] minute [ [ ":" ] second ]
  28 -- > hour        ::= 2DIGIT
  29 -- > minute      ::= 2DIGIT
  30 -- > second      ::= 2DIGIT
  31 -- > zone        ::= "GMT"              ; Universal Time
  32 -- >               | "NST"              ; Newfoundland: -3:30
  33 -- >               | "AST" | "ADT"      ; Atlantic    :  -4 /  -3
  34 -- >               | "EST" | "EDT"      ; Eastern     :  -5 /  -4
  35 -- >               | "CST" | "CDT"      ; Central     :  -6 /  -5
  36 -- >               | "MST" | "MDT"      ; Mountain    :  -7 /  -6
  37 -- >               | "PST" | "PDT"      ; Pacific     :  -8 /  -7
  38 -- >               | "YST" | "YDT"      ; Yukon       :  -9 /  -8
  39 -- >               | "HST" | "HDT"      ; Haw/Ala     : -10 /  -9
  40 -- >               | "BST" | "BDT"      ; Bering      : -11 / -10
  41 -- >               | "Z"                ; GMT
  42 -- >               | "A"                ;  -1
  43 -- >               | "M"                ; -12
  44 -- >               | "N"                ;  +1
  45 -- >               | "Y"                ; +12
  46 -- >               | ("+" | "-") 4DIGIT ; Local diff: HHMM
  47 module Data.Time.Format.RFC733
  48     ( RFC733
  49     , rfc733DateAndTime
  50     )
  51     where
  52 import Control.Applicative
  53 import Data.Ascii (Ascii, AsciiBuilder)
  54 import qualified Data.Ascii as A
  55 import Data.Attoparsec.Char8
  56 import Data.Convertible.Base
  57 import Data.Monoid.Unicode
  58 import Data.Tagged
  59 import Data.Time
  60 import Data.Time.Calendar.WeekDate
  61 import Data.Time.Format.HTTP.Common
  62 import Data.Time.Format.RFC822.Internal
  63 import Prelude.Unicode
  64
  65 -- |The phantom type for conversions between RFC 733 date and time
  66 -- strings and 'ZonedTime'.
  67 --
  68 -- >>> convertSuccess (ZonedTime (LocalTime (ModifiedJulianDay 49662) (TimeOfDay 8 49 37)) utc)
  69 -- Tagged "Sunday, 06-Nov-1994 08:49:37 GMT"
  70 data RFC733
  71
  72 instance ConvertSuccess ZonedTime (Tagged RFC733 Ascii) where
  73     {-# INLINE convertSuccess #-}
  74     convertSuccess = (A.fromAsciiBuilder <$>) ∘ cs
  75
  76 instance ConvertSuccess ZonedTime (Tagged RFC733 AsciiBuilder) where
  77     {-# INLINE convertSuccess #-}
  78     convertSuccess = Tagged ∘ toAsciiBuilder
  79
  80 instance ConvertAttempt (Tagged RFC733 Ascii) ZonedTime where
  81     {-# INLINE convertAttempt #-}
  82     convertAttempt = parseAttempt' rfc733DateAndTime ∘ untag
  83
  84 -- |Parse an RFC 733 date and time string.
  85 rfc733DateAndTime ∷ Parser ZonedTime
  86 rfc733DateAndTime = dateTime
  87
  88 dateTime ∷ Parser ZonedTime
  89 dateTime = do weekDay ← optionMaybe $
  90                         do w ← longWeekDayNameP
  91                                <|>
  92                                shortWeekDayNameP
  93                            _ ← string ", "
  94                            return w
  95               gregDay ← date
  96               case weekDay of
  97                 Nothing
  98                     → return ()
  99                 Just givenWD
 100                     → assertWeekDayIsGood givenWD gregDay
 101               (tod, timeZone) ← time
 102               let lt = LocalTime gregDay tod
 103                   zt = ZonedTime lt timeZone
 104               return zt
 105
 106 date ∷ Parser Day
 107 date = do day   ← read2
 108           _     ← char '-' <|> char ' '
 109           month ← try longMonthNameP
 110                   <|>
 111                   shortMonthNameP
 112           _     ← char '-' <|> char ' '
 113           year  ← try read4
 114                   <|>
 115                   (+ 1900) <$> read2
 116           _     ← char ' '
 117           assertGregorianDateIsGood year month day
 118
 119 time ∷ Parser (TimeOfDay, TimeZone)
 120 time = do tod ← hms
 121           _   ← char '-' <|> char ' '
 122           tz  ← zone
 123           return (tod, tz)
 124
 125 hms ∷ Parser TimeOfDay
 126 hms = do hour   ← read2
 127          _      ← optional (char ':')
 128          minute ← read2
 129          second ← option 0 $
 130                   do _ ← optional (char ':')
 131                      read2
 132          assertTimeOfDayIsGood hour minute second
 133
 134 zone ∷ Parser TimeZone
 135 zone = choice [ string "GMT" *> return (TimeZone 0 False "GMT")
 136               , char 'N'
 137                 *> choice [ string "ST" *> return (TimeZone ((-3) * 60 - 30) False "NST")
 138                           , return (TimeZone (1 * 60) False "N")
 139                           ]
 140               , char 'A'
 141                 *> choice [ string "ST" *> return (TimeZone ((-4) * 60) False "AST")
 142                           , string "DT" *> return (TimeZone ((-3) * 60) False "AST")
 143                           , return (TimeZone ((-1) * 60) False "A")
 144                           ]
 145               , char 'E'
 146                 *> choice [ string "ST" *> return (TimeZone ((-5) * 60) False "EST")
 147                           , string "DT" *> return (TimeZone ((-4) * 60) True  "EDT")
 148                           ]
 149               , char 'C'
 150                 *> choice [ string "ST" *> return (TimeZone ((-6) * 60) False "CST")
 151                           , string "DT" *> return (TimeZone ((-5) * 60) True  "CDT")
 152                           ]
 153               , char 'M'
 154                 *> choice [ string "ST" *> return (TimeZone ((-7) * 60) False "MST")
 155                           , string "DT" *> return (TimeZone ((-6) * 60) True  "MDT")
 156                           , return (TimeZone ((-12) * 60) False "M")
 157                           ]
 158               , char 'P'
 159                 *> choice [ string "ST" *> return (TimeZone ((-8) * 60) False "PST")
 160                           , string "DT" *> return (TimeZone ((-7) * 60) True  "PDT")
 161                           ]
 162               , char 'Y'
 163                 *> choice [ string "ST" *> return (TimeZone ((-9) * 60) False "YST")
 164                           , string "DT" *> return (TimeZone ((-8) * 60) True  "YDT")
 165                           , return (TimeZone ( 12  * 60) False "Y")
 166                           ]
 167               , char 'H'
 168                 *> choice [ string "ST" *> return (TimeZone ((-10) * 60) False "HST")
 169                           , string "DT" *> return (TimeZone (( -9) * 60) True  "HDT")
 170                           ]
 171               , char 'B'
 172                 *> choice [ string "ST" *> return (TimeZone ((-11) * 60) False "BST")
 173                           , string "DT" *> return (TimeZone ((-10) * 60) True  "BDT")
 174                           ]
 175               , char 'Z' *> return (TimeZone 0 False "Z")
 176               , read4digitsTZ
 177               ]
 178
 179 toAsciiBuilder ∷ ZonedTime → AsciiBuilder
 180 toAsciiBuilder zonedTime
 181     = let localTime          = zonedTimeToLocalTime zonedTime
 182           timeZone           = zonedTimeZone zonedTime
 183           (year, month, day) = toGregorian (localDay localTime)
 184           (_, _, week)       = toWeekDate  (localDay localTime)
 185           timeOfDay          = localTimeOfDay localTime
 186       in
 187         longWeekDayName week
 188         ⊕ A.toAsciiBuilder ", "
 189         ⊕ show2 day
 190         ⊕ A.toAsciiBuilder "-"
 191         ⊕ shortMonthName month
 192         ⊕ A.toAsciiBuilder "-"
 193         ⊕ show4 year
 194         ⊕ A.toAsciiBuilder " "
 195         ⊕ show2 (todHour timeOfDay)
 196         ⊕ A.toAsciiBuilder ":"
 197         ⊕ show2 (todMin timeOfDay)
 198         ⊕ A.toAsciiBuilder ":"
 199         ⊕ show2 (floor (todSec timeOfDay) ∷ Int)
 200         ⊕ A.toAsciiBuilder " "
 201         ⊕ untag (cs timeZone ∷ Tagged RFC822 AsciiBuilder)
 202
 203 deriveAttempts [ ([t| ZonedTime |], [t| Tagged RFC733 Ascii        |])
 204                , ([t| ZonedTime |], [t| Tagged RFC733 AsciiBuilder |])
 205                ]