Network/HTTP/Lucu/ETag.hs

   1 {-# LANGUAGE
   2     OverloadedStrings
   3   , UnicodeSyntax
   4   #-}
   5 -- |Manipulation of entity tags.
   6 module Network.HTTP.Lucu.ETag
   7     ( ETag(..)
   8     , parseETag
   9     , printETag
  10
  11     , strongETag
  12     , weakETag
  13     , eTagP
  14     , eTagListP
  15     )
  16     where
  17 import Control.Applicative
  18 import Control.Monad
  19 import Data.Ascii (Ascii)
  20 import qualified Data.Ascii as A
  21 import Data.Attoparsec.Char8
  22 import Data.Monoid.Unicode
  23 import Network.HTTP.Lucu.Parser.Http hiding (token)
  24 import Network.HTTP.Lucu.Utils
  25 import Prelude.Unicode
  26
  27 -- |An entity tag is made of a weakness flag and a opaque string.
  28 data ETag = ETag {
  29       -- |The weakness flag. Weak tags looks like W\/\"blahblah\" and
  30       -- strong tags are like \"blahblah\".
  31       etagIsWeak ∷ !Bool
  32       -- |An opaque string. Only characters from 0x20 (sp) to 0x7e (~)
  33       -- are allowed.
  34     , etagToken  ∷ !Ascii
  35     } deriving (Eq, Show)
  36
  37 -- |Convert an 'ETag' to 'Ascii'.
  38 printETag ∷ ETag → Ascii
  39 printETag et
  40     = A.fromAsciiBuilder $
  41       ( ( if etagIsWeak et then
  42               A.toAsciiBuilder "W/"
  43           else
  44               (∅)
  45         )
  46         ⊕
  47         quoteStr (etagToken et) )
  48
  49 -- |Parse 'Etag' from an 'Ascii'. This functions throws an exception
  50 -- for parse error.
  51 parseETag ∷ Ascii → ETag
  52 parseETag str
  53     = let p  = do et ← eTagP
  54                   endOfInput
  55                   return et
  56           bs = A.toByteString str
  57       in
  58         case parseOnly p bs of
  59           Right et → et
  60           Left err → error ("unparsable ETag: " ⧺ A.toString str ⧺ ": " ⧺ err)
  61
  62 -- |This is equivalent to @'ETag' 'Prelude.False'@. If you want to
  63 -- generate an ETag from a file, try using
  64 -- 'Network.HTTP.Lucu.StaticFile.generateETagFromFile'.
  65 strongETag ∷ Ascii → ETag
  66 strongETag = ETag False
  67
  68 -- |This is equivalent to @'ETag' 'Prelude.True'@.
  69 weakETag ∷ Ascii → ETag
  70 weakETag = ETag True
  71
  72 eTagP ∷ Parser ETag
  73 eTagP = do isWeak ← option False (string "W/" *> return True)
  74            str    ← quotedStr
  75            return $ ETag isWeak str
  76
  77 eTagListP ∷ Parser [ETag]
  78 eTagListP = do xs ← listOf eTagP
  79                when (null xs) $
  80                    fail "empty list of ETags"
  81                return xs