Network/HTTP/Lucu/ETag.hs

   1 {-# LANGUAGE
   2     OverloadedStrings
   3   , UnicodeSyntax
   4   #-}
   5 -- |Manipulation of entity tags.
   6 module Network.HTTP.Lucu.ETag
   7     ( ETag(..)
   8     , parseETag
   9     , printETag
  10
  11     , strongETag
  12     , weakETag
  13     , eTagP
  14     , eTagListP
  15     )
  16     where
  17 import Control.Applicative
  18 import Control.Monad
  19 import Data.Ascii (Ascii, AsciiBuilder)
  20 import qualified Data.Ascii as A
  21 import Data.Attoparsec.Char8
  22 import Data.Monoid.Unicode
  23 import Network.HTTP.Lucu.Parser.Http hiding (token)
  24 import Network.HTTP.Lucu.Utils
  25 import Prelude.Unicode
  26
  27 -- |An entity tag is made of a weakness flag and a opaque string.
  28 data ETag = ETag {
  29       -- |The weakness flag. Weak tags looks like W\/\"blahblah\" and
  30       -- strong tags are like \"blahblah\".
  31       etagIsWeak ∷ !Bool
  32       -- |An opaque string. Only characters from 0x20 (sp) to 0x7e (~)
  33       -- are allowed.
  34     , etagToken  ∷ !Ascii
  35     } deriving (Eq, Show)
  36
  37 -- |Convert an 'ETag' to 'AsciiBuilder'.
  38 printETag ∷ ETag → AsciiBuilder
  39 printETag et
  40     = ( if etagIsWeak et then
  41             A.toAsciiBuilder "W/"
  42         else
  43             (∅)
  44       )
  45       ⊕
  46       quoteStr (etagToken et)
  47
  48 -- |Parse 'Etag' from an 'Ascii'. This functions throws an exception
  49 -- for parse error.
  50 parseETag ∷ Ascii → ETag
  51 parseETag str
  52     = let p  = do et ← eTagP
  53                   endOfInput
  54                   return et
  55           bs = A.toByteString str
  56       in
  57         case parseOnly p bs of
  58           Right et → et
  59           Left err → error ("unparsable ETag: " ⧺ A.toString str ⧺ ": " ⧺ err)
  60
  61 -- |This is equivalent to @'ETag' 'Prelude.False'@. If you want to
  62 -- generate an ETag from a file, try using
  63 -- 'Network.HTTP.Lucu.StaticFile.generateETagFromFile'.
  64 strongETag ∷ Ascii → ETag
  65 strongETag = ETag False
  66
  67 -- |This is equivalent to @'ETag' 'Prelude.True'@.
  68 weakETag ∷ Ascii → ETag
  69 weakETag = ETag True
  70
  71 eTagP ∷ Parser ETag
  72 eTagP = do isWeak ← option False (string "W/" *> return True)
  73            str    ← quotedStr
  74            return $ ETag isWeak str
  75
  76 eTagListP ∷ Parser [ETag]
  77 eTagListP = do xs ← listOf eTagP
  78                when (null xs) $
  79                    fail "empty list of ETags"
  80                return xs