Data/Time/Asctime.hs

   1 {-# LANGUAGE
   2     FlexibleInstances
   3   , MultiParamTypeClasses
   4   , OverloadedStrings
   5   , UnicodeSyntax
   6   #-}
   7 -- |This module provides functions for ANSI C's asctime() format.
   8 --
   9 -- ANSI C's asctime() format looks like:
  10 --
  11 -- @Wdy Mon [D]D HH:MM:SS YYYY@
  12 --
  13 -- The exact syntax is as follows:
  14 --
  15 -- > date-time ::= wday SP month SP day SP time SP year
  16 -- > wday      ::= "Mon" | "Tue" | "Wed" | "Thu"
  17 -- >             | "Fri" | "Sat" | "Sun"
  18 -- > month     ::= "Jan" | "Feb" | "Mar" | "Apr"
  19 -- >             | "May" | "Jun" | "Jul" | "Aug"
  20 -- >             | "Sep" | "Oct" | "Nov" | "Dec"
  21 -- > day       ::= 2DIGIT | SP 1DIGIT
  22 -- > time      ::= 2DIGIT ':' 2DIGIT [':' 2DIGIT]
  23 -- > year      ::= 4DIGIT
  24 --
  25 -- As you can see, it has no time zone info. "Data.Time.HTTP" will
  26 -- treat it as UTC.
  27 module Data.Time.Asctime
  28     ( Asctime
  29     , asctime
  30     )
  31     where
  32 import Control.Applicative
  33 import Data.Ascii (Ascii, AsciiBuilder)
  34 import qualified Data.Ascii as A
  35 import Data.Attoparsec.Char8
  36 import Data.Convertible.Base
  37 import Data.Monoid.Unicode
  38 import Data.Tagged
  39 import Data.Time
  40 import Data.Time.Calendar.WeekDate
  41 import Data.Time.HTTP.Common
  42 import Prelude.Unicode
  43
  44 -- |The phantom type for conversion between ANSI C's @asctime()@
  45 -- string and 'LocalTime'.
  46 data Asctime
  47
  48 instance ConvertSuccess LocalTime (Tagged Asctime Ascii) where
  49     {-# INLINE convertSuccess #-}
  50     convertSuccess = (A.fromAsciiBuilder <$>) ∘ cs
  51
  52 instance ConvertAttempt LocalTime (Tagged Asctime Ascii) where
  53     {-# INLINE convertAttempt #-}
  54     convertAttempt = return ∘ cs
  55
  56 instance ConvertSuccess LocalTime (Tagged Asctime AsciiBuilder) where
  57     {-# INLINE convertSuccess #-}
  58     convertSuccess = Tagged ∘ toAsciiBuilder
  59
  60 instance ConvertAttempt LocalTime (Tagged Asctime AsciiBuilder) where
  61     {-# INLINE convertAttempt #-}
  62     convertAttempt = return ∘ cs
  63
  64 instance ConvertAttempt (Tagged Asctime Ascii) LocalTime where
  65     {-# INLINE convertAttempt #-}
  66     convertAttempt = parseAttempt' asctime ∘ untag
  67
  68 -- |Parse an ANSI C's @asctime()@ string.
  69 asctime ∷ Parser LocalTime
  70 asctime = do weekDay ← shortWeekDayNameP
  71              _       ← char ' '
  72              month   ← shortMonthNameP
  73              _       ← char ' '
  74              day     ← read2'
  75              _       ← char ' '
  76              hour    ← read2
  77              _       ← char ':'
  78              minute  ← read2
  79              _       ← char ':'
  80              second  ← read2
  81              _       ← char ' '
  82              year    ← read4
  83
  84              gregDay ← assertGregorianDateIsGood year month day
  85              _       ← assertWeekDayIsGood weekDay gregDay
  86              tod     ← assertTimeOfDayIsGood hour minute second
  87
  88              return (LocalTime gregDay tod)
  89
  90 toAsciiBuilder ∷ LocalTime → AsciiBuilder
  91 toAsciiBuilder localTime
  92     = let (year, month, day) = toGregorian (localDay localTime)
  93           (_, _, week)       = toWeekDate  (localDay localTime)
  94           timeOfDay          = localTimeOfDay localTime
  95       in
  96         shortWeekDayName week
  97         ⊕ A.toAsciiBuilder " "
  98         ⊕ shortMonthName month
  99         ⊕ A.toAsciiBuilder " "
 100         ⊕ show2' day
 101         ⊕ A.toAsciiBuilder " "
 102         ⊕ show2 (todHour timeOfDay)
 103         ⊕ A.toAsciiBuilder ":"
 104         ⊕ show2 (todMin timeOfDay)
 105         ⊕ A.toAsciiBuilder ":"
 106         ⊕ show2 (floor (todSec timeOfDay) ∷ Int)
 107         ⊕ A.toAsciiBuilder " "
 108         ⊕ show4 year